#This rule is for dealing with photons, see the bottom modifications for more details
'PhotRadiat'  -> Photon(act) @ 0
'PhotDe-Rad' Photon(act) -> @ 0

#This rule details the activation of lovTAP by photons; it may have to be changed to accomodate QuantumYield in a !population model
'PhotoActiv' lovTAP(dim~Off, act~Off), Photon(act) -> lovTAP(dim~Off, act~On) @ $INF

#These deal with the equilibrium of active/inactive lovTAP as well as active/inactive dimerized lovTAP
'lovTAP_eq1' lovTAP(dim~Off, act~Off) <-> lovTAP(dim~Off, act~On) @ 0.001, 1.0
'lovTAP_eq2' lovTAP(dim~Off, act~On), lovTAP(dim~Off, act~On) <-> lovTAP(dim~On, act~On) @ 0.1, 0.1

#This is the binding of dimerized lovTAP to the TrpL site
'lovTAP_ocp' TrpL(act), lovTAP(dim~On, act~On) <-> TrpL(act!1), lovTAP(dim~On!1, act~On) @ 0.1, 0.1

#This is the basal production of protein pCI by an un-occupied TrpL site
'TrpL_BsPrd' TrpL(act) -> TrpL(act), pCI(act) @ 12.0

#This is the degradation of pCI
'pCI-Degrad' pCI(act?) ->  @ 0.5

#This is the binding equilibrium of pCI to the site sCI
'pCI-Bd-sCI' pCI(act), sCI(act) <-> pCI(act!1), sCI(act!1) @ 0.1, 0.1

#This is the basal production of an un-occupied sCI site
'sCIBaseExp' sCI(act) -> sCI(act), mRNA() @ 1.0

%init: 3000 * (lovTAP(dim~Off, act~Off))
%init: 30 * (TrpL(act), sCI(act))

#%obs: 'lovTAP single Off' lovTAP(dim~Off, act~Off)
#%obs: 'lovTAP single On' lovTAP(dim~Off, act~On)
%obs: 'lovTAP double On' lovTAP(dim~On, act~On)
%obs: 'pCI' pCI(act)
%obs: 'mRNA' mRNA()

#This modification irradiates the system with 5000 photons per second for 10 seconds, at the end of which ALL photons disappear
%mod: $T>20.0 do 'PhotRadiat':=5000
%mod: $T>30.0 do 'PhotRadiat':=0
%mod: $T>30.0 do 'PhotDe-Rad':=$INF